using terms from application "Quicksilver"
  on process text ffd
    my growlRegister()
    tell application "Keychain Scripting"
      set ffd_key to first Internet key of current keychain whose server is "friendfeed.com"
      set ffd_login to quoted form of (account of ffd_key & ":" & password of ffd_key)
    end tell
    set ffd_title to quoted form of ("title=" & ffd & "&link=http://friendfeed.com/")
    set results to do shell script "curl -u " & ffd_login & " -d " & ffd_title & " http://friendfeed.com/api/share"
    
    growlNotify("Message Sent", ffd)
  end process text
end using terms from

using terms from application "GrowlHelperApp"
  on growlRegister()
    tell application "GrowlHelperApp"
      register as application "ffd" all notifications {"Alert"} default notifications {"Alert"} icon of application "Script Editor.app"
    end tell
  end growlRegister
  
  on growlNotify(grrTitle, grrDescription)
    tell application "GrowlHelperApp"
      notify with name "Alert" title grrTitle description grrDescription application name "ffd"
    end tell
  end growlNotify
end using terms from